Weekend Project – Arduino Temperature Meter

Material Needed: 

• Arudino Mini Pro * 1
• LCD Module 4 x 20 (J204A) * 1
• Temperature Probe (DS18B20) * 1 
• Protoboard * 1 
• 22k resistor * 1
• Few jumper wires

Wiring:

1. Arduino-GND to GND 
2. Arduino-VCC to VCC 
3. Temperature probe-GND to GND 
4. Temperature probe-VCC to VCC 
5. Temperature probe-Data to 2.2K resistor to VCC 
6. LCD-GND to GND 
7. LCD-VCC to VCC 
8. LCD-SDA to Arduino A4/SDA 
9. LCD-SLC to Arduino A5/SLC 
10. Protoboard VCC/GND to 5V DC power source 
11. Slide switch to VCC/GND (For LCD on/Off, but not shown below)

//Library version:1.1
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
//Used for DS18S20 Temperature sensor
#include <OneWire.h>
#include <DallasTemperature.h>

/*Define for DS18S20 data pins
*  This data pins needs to connect 220 Om resister and to 5V to work
*/
#define ONE_WIRE_BUS 4 

//Define for LCD display pins, SLC 3, SDA 2
#define SCL_CLOCK_PIN 3
#define SDA_DATA_PIN 2

//Initialize OneWire library for temperature sensor
OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);

// set the LCD address to 0x27 for a 20 chars and 4 line display
LiquidCrystal_I2C lcd(0x27,20,4);  

float HighestTemp = 0.0;
float CurrentTemp = 0.0;
float LowestTemp = 0.0;

void setup()
{
  // start temperature sensor
  sensors.begin();
  sensors.requestTemperatures(); //get temperature
  // initialize the LCD
  //You may setup your own clock pin(SCL), data pin(SDA) 2013-12-14
  //Wire.beginOnPins(SCL_CLOCK_PIN, SDA_DATA_PIN);
  lcd.init();
  
  lcd.backlight();
  
  //Set lowest, highest temperatues 
  CurrentTemp  = sensors.getTempCByIndex(0);
  HighestTemp = CurrentTemp;
  LowestTemp = CurrentTemp;
  
  lcd.setCursor(0,0);  
  lcd.print(F("=Temperature Meter="));

  lcd.setCursor(0,1);
  lcd.print(F("Highest: "));
  LCDshowNum(8,1,HighestTemp);    
     
  lcd.setCursor(0,2);
  lcd.print(F("Current: "));
  LCDshowNum(8,2,CurrentTemp);  
    
  lcd.setCursor(0,3);
  lcd.print(F("Lowest: "));
  LCDshowNum(8,3,LowestTemp);     
}


void loop()
{ 
  sensors.requestTemperatures(); //get temperature

  //Get Current
  CurrentTemp = sensors.getTempCByIndex(0);
  LCDshowNum(8,2,CurrentTemp);   
  
  //Check if Hightest
  if(CurrentTemp > HighestTemp){
     HighestTemp = CurrentTemp;
     LCDshowNum(8,1,HighestTemp);     
  }

  //Chekc if Lowest
  if(CurrentTemp < LowestTemp){
    LowestTemp = CurrentTemp;
    LCDshowNum(8,3,LowestTemp);
  }

  delay(1);
}

/*
* LCDshowNum
* LCD display location: x, y
* Float n: temperature to display
*/
void LCDshowNum(int x, int y, float n){
  lcd.setCursor(x,y);
  lcd.print(n);
}

自製 Arduino 溫度測量機

在這個教學中，我會教你們怎麼做一個可以讓你在ＬＣＤ模型上測量出目前的溫度，最高的溫度和最低的溫度的「溫度測量機」。在我完成它之後，我把它放在桌子上大約一個星期後，它還在運作呢！☺ 我覺得是時候該跟大家分享我是怎麼製作它了。

 看看我的溫度測量機：

需要材料： 

• Arudino Mini Pro * 1 
• LCD 模組 4 x 20 (J204A) * 1 
• 溫度探棒 (DS18B20) * 1 
• 洞洞板 * 1 
• 22k 電阻 * 1 
• 幾根跳線

底下的影片中，一共有三個瓶子，分別裝著熱水，冰水和常溫的水。
我請我的兒子把溫度探棒分別置入到每一個瓶子裡，再觀查各別溫度的變化。

我兒子問我：「有沒有可能讓溫度降到零度或更低？」我們很快的從網路上找到了答案。其實很簡單，只要在冰塊上撒鹽。過了大約一分鐘，溫度就降到了-11度 Ｃ(我們最低該溫度降到到-14.31度 C)！看著溫度快速的上升又急快的下降真有趣！請看底下的影片：

 找個時間做這個Arduino 專案，再和小朋友一起同樂吧！

 Stonez